Clinical Endocrinology/Clinical Endocrinology.iso/pc/00000000/14000000/14020000/shared.dir/00910_Script_910

Text File | 1995-11-17 | 7KB | 261 lines

-- Handler to switch to zoomed screen from
-- main screen.

on clickOnSmallPict

  put the frameLabel into jumpToLabel
  sound playFile 1, "Click.aif"
  set the visibility of sprite 5 to false -- picture
  set the visibility of sprite 6 to false -- caption

  set the visibility of sprite 36 to false -- slider
  set the visibility of sprite 37 to false -- slider

  go label (jumpToLabel&"z") - 1
  updatestage
  go label (jumpToLabel&"z")
  put the castNum of sprite 6 into theCast

  set the forecolor of cast theCast to 0
  set the backcolor of cast theCast to 255
  set the visibility of sprite 5 to true -- picture
  set the visibility of sprite 6 to true -- caption

end clickOnSmallPict

----------------------------------------------
-- Handler to switch back to main screen from
-- zoomed screen.

on clickOnBigPict

  put the frameLabel into theLabel
  put the number of chars in theLabel into theChars
  put char 1 to ( theChars - 1)  of theLabel into jumpToLabel


  sound playFile 1, "Click.aif"
  puppetSprite 5, false
  puppetSprite 6, false
  go the frame - 1
  --puppetPalette 924 -- change to mac system palette
  --puppetPalette 0 -- turn off puppeting
  go frame jumpToLabel
  set the visibility of sprite 6 to true
  set the visibility of sprite 36 to true
  set the visibility of sprite 37 to true

end clickOnBigPict
----------------------------------------------
-- Handler to stick the zoomed pict to the mouse

on moveBigPict

  cursor 200
  put the clickOn into whichSprite
  puppetSprite whichSprite, true

  put the locH of sprite whichSprite - the mouseH into Hdiff
  put the locV of sprite whichSprite - the mouseV into Vdiff
  repeat while the stillDown
    set the locH of sprite whichSprite to the mouseH + Hdiff
    set the locV of sprite whichSprite to the mouseV + Vdiff
    updateStage
  end repeat


  cursor -1

end moveBigPict

----------------------------------------------
-- handler to switch the big caption on or off

on captionSwitch

  if the visibility of sprite 6 = 1 then
    set the visibility of sprite 6 = 0
  else
    set the visibility of sprite 6 = 1
  end if
end captionSwitch

---------------------------------------------------------------
-- When a word in the tools
-- menu is rooled on it flashes red and if it is clicked
-- then the script in quotes is executed. Here the script
-- should be a call to open a MIAW.

on toolsDrop

  if rollOver(17) = true then
    flashButton 17, "openSearch"

  else if rollOver(18) = true then
    flashButton 18, "openNotes"

  else if rollOver(19) = true then
    flashButton 19, "openBookmarks"

  else if rollOver(20) = true then
    flashButton 20, "wait 10"

  end if

end toolsDrop
------------------------------------------
-- This handler is called when the tools button is pressed.
-- It puts the frame it is called from into a global variable
-- so that it can remember to return to the same spot.
-- The channels containing text, diagrams, and active buttons,
-- are puppeted to freeze them while the menu is down in the
-- frame "menu".

on toolsScript

  global jumpFrame

  put the frame into jumpFrame
  puppetsOn
  go frame "tools"

end toolsScript
------------------------------------------
-- Handler to open the MIAW for searching topics.

on openSearch

  global hardDisk

  -- Define Window boundaries
  set theTop = the stageTop + 140
  set theLeft = the stageLeft + 56
  set theBottom = theTop + 200
  set theRight = theLeft + 528

  put  hardDisk & "Search.dir" into childWindow
  set the rect of window childWindow = rect(theLeft,theTop,theRight,theBottom)
  set the title of window childWindow to "Search"
  set the windowType of window childWindow to 4
  --set the modal of window childWindow to true
  open window childWindow

end openSearch
------------------------------------------
-- Handler to open the MIAW for making notes.

on openNotes

  global hardDisk

  -- Define Window boundaries
  set theTop = the stageTop + 70
  set theLeft = the stageLeft + 25
  set theBottom = theTop + 368
  set theRight = theLeft + 256

  put  hardDisk & "Notes.dir" into childWindow
  set the rect of window childWindow = rect(theLeft,theTop,theRight,theBottom)
  set the windowType of window childWindow to 4
  --set the modal of window childWindow to TRUE
  set the title of window childWindow to "Notes"
  open window childWindow

end openNotes
------------------------------------------
-- Handler to open the MIAW for making bookmarks.

on openBookmarks

  global hardDisk

  -- Define Window boundaries
  set theTop = the stageTop + 140
  set theLeft = the stageLeft + 112
  set theBottom = theTop + 200
  set theRight = theLeft + 416

  put  hardDisk & "Bookmark.dir" into childWindow
  set the rect of window childWindow = rect(theLeft,theTop,theRight,theBottom)
  set the title of window childWindow to "Bookmarks"
  open window childWindow

end openBookmarks
------------------------------------------
-- Handler called when bottom left buttons are clicked
-- or slidebox button. A specific handler is called
-- appropriate to the function.

on navButtCheck
  put the clickOn into whichSprite

  if the clickOn = 31 then
    goUpLevel

  else if the clickOn = 32 then
    goBackOne

  else if the clickOn = 34 then
    goSlideBox

  else if the clickOn = 35 then
    goSlideCopy

  else if the clickOn = 38 then
    quitScript

  end if

end navButtCheck
------------------------------------------
on goUpLevel

  global CDDrive, gSep

  go movie CDDrive & "00000000" & gSep & "00000000.dir"

end goUpLevel
------------------------------------------
on goBackOne
  global hardDisk

  put hardDisk & "History.dir" into childWindow
  if the visible of window childWindow = true then
    set the visible of window childWindow = false
    set the modal of window childWindow to false
  else
    set the windowType of window childWindow = 4
    set the visible of window childWindow = true
    set the modal of window childWindow to true
  end if


end goBackOne
------------------------------------------
on goSlideCopy

  copySlide

end goSlideCopy
-----------------------------------------------
-----------------------------------------------
-- Handler called from Q button to quit from the CD

on quitScript

  global hardDisk

  -- Define Window boundaries
  set theTop = the stageTop + 140
  set theLeft = the stageLeft + 178
  set theBottom = theTop + 200
  set theRight = theLeft + 304

  put  hardDisk & "Quit.dir" into childWindow
  set the rect of window childWindow = rect(theLeft,theTop,theRight,theBottom)
  set the windowType of window childWindow to 2

  open window childwindow

end quitScript